Document.ExportEx method - Developer Area

API Documentation > Corel DESIGNER > 2017.1 > Document > IVGDocument

Document.ExportEx method

Exports a document to a supported non-native file format and returns an instance of ExportFilter

Syntax:

Function ExportEx(ByVal FileName As String, ByVal Filter As cdrFilter, Optional ByVal Range As cdrExportRange = cdrCurrentPage, Optional ByVal Options As StructExportOptions = Nothing, Optional ByVal PaletteOptions As StructPaletteOptions = Nothing) As ExportFilter

Parameters:

Name	Type	Description
FileName	String	Specifies the name of the document you are saving
Filter	cdrFilter	Specifies the filter that is used when saving objects, accepting a value of cdrFilter.
Range	cdrExportRange	Specifies the pages that are exported, accepting a value of cdrExportRange.
Options	StructExportOptions	Specifies the Save options of the exported document.
PaletteOptions	StructPaletteOptions	Specifies the set of options to apply when exporting to a paletted bitmap.

Remarks:

The ExportEx method exports a document, with specified options, to another file format, and returns an ExportFilter object. This function uses the StructExportOptions and StructPaletteOptions objects to specify image conversion and export parameters.

The ExportEx method returns an ExportFilter object that should be used to set additional filter parameters (such as JPEG compression, GIF transparent color, and so on) and finish the export.

Examples:

The following VBA example exports the newly created document to GIF format, allowing the user to set GIF properties and ensure that the image is interlaced.

Sub Test()
  Dim d As Document
  Dim s As Shape
  Dim opt As New StructExportOptions
  Dim pal As New StructPaletteOptions
  Dim Filter As ExportFilter
  Set d = CreateDocument
  Set s = d.ActiveLayer.CreateEllipse2(4, 5, 2)
  s.Fill.ApplyFountainFill CreateRGBColor(255, 0, 0), CreateRGBColor(0, 0, 0)
  opt.AntiAliasingType = cdrNormalAntiAliasing
  opt.ImageType = cdrRGBColorImage
  opt.ResolutionX = 72
  opt.ResolutionY = 72
  pal.PaletteType = cdrPaletteOptimized
  pal.NumColors = 16
  pal.DitherType = cdrDitherNone
  Set Filter = d.ExportEx("C:\Temp\Doc.gif", cdrGIF, cdrCurrentPage, opt, pal)
  If Filter.ShowDialog() Then
    If Not Filter.Interlaced Then
      MsgBox "Interlaced is not specified... Fixing this."
      Filter.Interlaced = True
    End If
    Filter.Finish
  Else
    MsgBox "Export canceled"
  End If
End Sub

Version Information:

CorelDRAW:	X7.4, X7, X7.6, X8, 2017, 2018, 2019, 2019.2, 2020, 2021, 2020.1, 2021.5, 2022-v24, 2022-v24.1, 2022-v24.2, 2023-v24.3, 2023-v24.5, 2024-v25
Corel DESIGNER:	X7, 2017.1, 20.1, 2019.2, 2020.1, 2021.5, 2022-v24, 2022-v24.1, 2022-v24.2, 2023-v24.3, 2023-v24.5, 2024-v25