StructPaletteOptions.Palette property - Developer Area

API Documentation > CorelDRAW > 2020 > StructPaletteOptions > IVGStructPaletteOptions

StructPaletteOptions.Palette property

Syntax:

Property Get Palette() As Variant
Property Let Palette(ByVal Value As Variant)

Remarks:

The Palette property specifies the palette when exporting a full-color image to a paletted bitmap.

Examples:

The following VBA example exports a document with the new custom color palette:

Sub Test()
  Dim d As Document
  Dim e As ExportFilter
  Dim s As Shape
  Dim sp As New StructPaletteOptions
  Dim p As Palette
  Set d = CreateDocument
  Set s = d.ActiveLayer.CreateRectangle(3, 3, 7, 7)
  s.Fill.ApplyFountainFill CreateRGBColor(255, 0, 0), CreateRGBColor(0, 0, 255)
  ' Change the palette type to custom.
  sp.PaletteType = cdrPaletteCustom
  ' Create a new palette and add some colors.
  Set p = Palettes.Create("Temp")
  p.AddColor CreateRGBColor(255, 0, 0)
  p.AddColor CreateRGBColor(0, 0, 255)
  p.AddColor CreateRGBColor(0, 255, 0)
  ' Set the palette to use for the export to the newly created palette.
  sp.Palette = p
  d.Export "C:\Test_ExportPalette_Passing_a_Palette.gif", cdrGIF, , , sp
End Sub

The following VBA example exports a document with a custom palette that is identified by its path and filename:

Sub Test()
  Dim d As Document
  Dim e As ExportFilter
  Dim s As Shape
  Dim sp As New StructPaletteOptions
  Set d = CreateDocument
  Set s = d.ActiveLayer.CreateRectangle(3, 3, 7, 7)
  s.Fill.ApplyFountainFill CreateRGBColor(255, 0, 0), CreateRGBColor(0, 0, 255)
  ' Change the palette type to custom.
  sp.PaletteType = cdrPaletteCustom
  ' Set the palette to use for the export to the filename of the existing palette.
  sp.Palette = SetupPath & "Custom Data\Palettes\CMYK\Nature\cEarthy.xml"
  d.Export "C:\Test_ExportPalette_Passing_a_Filename.gif", cdrGIF, , , sp
End Sub

The following VBA example exports a document with a custom palette that is defined by an array of long values (which represent colors):

Sub Test()
  Dim d As Document
  Dim e As ExportFilter
  Dim s As Shape
  Dim sp As New StructPaletteOptions
  Set d = CreateDocument
  Set s = d.ActiveLayer.CreateRectangle(3, 3, 7, 7)
  s.Fill.ApplyFountainFill CreateRGBColor(255, 0, 0), CreateRGBColor(0, 0, 255)
  ' Change the palette type to custom.
  sp.PaletteType = cdrPaletteCustom
  ' Set the palette to use for the export to an array of longs which represent the colors to use.
  sp.Palette = Array(RGB(255, 0, 0), RGB(0, 0, 255), RGB(125, 0, 0), RGB(0, 0, 125), RGB(155, 0, 0), RGB(0, 0, 155), RGB(175, 32, 175))
  d.Export "C:\Test_ExportPalette_Passing_an_array_of_longs.gif", cdrGIF, , , sp
End Sub

The following VBA example exports a document with a custom palette that is defined by an array of colors:

Sub Test()
  Dim d As Document
  Dim e As ExportFilter
  Dim s As Shape
  Dim sp As New StructPaletteOptions
  Set d = CreateDocument
  Set s = d.ActiveLayer.CreateRectangle(3, 3, 7, 7)
  s.Fill.ApplyFountainFill CreateRGBColor(255, 0, 0), CreateRGBColor(0, 0, 255)
  ' Change the palette type to custom
  sp.PaletteType = cdrPaletteCustom
  ' Set the palette to use for the export to an array of colors
  sp.Palette = Array(CreateCMYKColor(0, 77, 23, 23), CreateCMYKColor(10, 23, 43, 54), CreateCMYKColor(54, 12, 88, 12))
  d.Export "C:\Test_ExportPalette_Passing_an_array_of_colors.gif", cdrGIF, , , sp
End Sub

Version Information:

CorelDRAW:	X7.4, X7, X7.6, X8, 2017, 2018, 2019, 2019.2, 2020, 2021, 2020.1, 2021.5, 2022-v24, 2022-v24.1, 2022-v24.2, 2023-v24.3, 2023-v24.5, 2024-v25
Corel DESIGNER:	X7, 2017.1, 20.1, 2019.2, 2020.1, 2021.5, 2022-v24, 2022-v24.1, 2022-v24.2, 2023-v24.3, 2023-v24.5, 2024-v25