RGB to CMYK clipart color conversion

Never mind :-)

Edit -> Find and Replace -> Replace Objects -> Replace a color model or palette... and so on.

Also a couple of my favorite macros by Alex Posterize and Limit Colors.

'begin script.........................................................................

Option Explicit

Public Sub ConvertAllColorsToCMYK() 'run this sub
    ConvertShapes ActivePage.Shapes
End Sub

Private Sub ConvertShapes(ss As Shapes)
    Dim s As Shape
   
    For Each s In ss
        Select Case s.Type
            Case cdrTextShape, cdrRectangleShape, cdrPolygonShape, _
                 cdrLinearDimensionShape, cdrEllipseShape, cdrCurveShape, _
                 cdrConnectorShape, cdrBitmapShape
                
                ConvertShapeColors s
               
            Case cdrGroupShape
                ConvertShapes s.Shapes
        End Select
        On Error Resume Next
        If Not s.PowerClip Is Nothing Then
            ConvertShapes s.PowerClip.Shapes
        End If
    Next s
End Sub

Private Sub ConvertShapeColors(s As Shape)
    Dim C As FountainColor
    ' 1. Convert Fill colors
    Select Case s.Fill.Type
        Case cdrUniformFill
            ConvertColor s.Fill.UniformColor
           
        Case cdrPatternFill
            ConvertColor s.Fill.Pattern.FrontColor
            ConvertColor s.Fill.Pattern.BackColor
           
        Case cdrFountainFill
            ConvertColor s.Fill.Fountain.StartColor
            ConvertColor s.Fill.Fountain.EndColor
            For Each C In s.Fill.Fountain.Colors
                ConvertColor C.Color
            Next C
    End Select
   
    ' 2. Convert outline color
    If s.Outline.Type = cdrOutline Then
        ConvertColor s.Outline.Color
    End If
End Sub

Private Sub ConvertColor(C As Color)
    C.ConvertToCMYK
End Sub

'end script.........................................................................

-John