Centre of Circle - Show & Print

BigKev said:

If necessary I will re-create my pattern but thought I'd seek some advice first as to whether there is a way to magically show and print a circle's centre which clearly would save me some time.

You could also use a macro to add center marks; something like this:

Sub centermark_ellipses()
Dim sr As ShapeRange
Dim s As Shape
Const dblMarkL As Double = 5
    
    ActiveDocument.SaveSettings
    ActiveDocument.Unit = cdrMillimeter
    EventsEnabled = False
    Optimization = True
    ActiveDocument.BeginCommandGroup "center marks"
    
    On Error GoTo ErrHandler
       
    Set sr = ActivePage.Shapes.FindShapes(, cdrEllipseShape)
    
    For Each s In sr
    
        ActiveLayer.CreateLineSegment s.CenterX - dblMarkL / 2, s.CenterY, s.CenterX + dblMarkL / 2, s.CenterY
        ActiveLayer.CreateLineSegment s.CenterX, s.CenterY - dblMarkL / 2, s.CenterX, s.CenterY + dblMarkL / 2

    Next s

ExitSub:
    ActiveDocument.EndCommandGroup
    Optimization = False
    EventsEnabled = True
    ActiveDocument.RestoreSettings
    Application.Refresh
    Exit Sub

ErrHandler:
    MsgBox "Error occurred: " & Err.Description
    Resume ExitSub
End Sub

That code should find all of the ellipse shapes. For each of those shapes, it will add a horizontal line and a vertical line that together serve as a center mark for that shape.

Those lines will be created on the active layer, and will have whatever outline characteristics (e.g., line width, color, etc.) are currently set in the document for new graphic objects.

The length of those lines is set in the code here:

Const dblMarkL As Double = 5

This:

becomes this: