Text Stretching when Pasting from pdf or opening a cgm

Would you please upload a .CDR file that has some examples of the "stretched" text in it?

When replying, you can click on the "Use rich formatting" link. That takes you to an editor that includes a button for "Insert/Edit media" that should allow you to upload a file.

1513.Test.cdr

Hi Eskimo, here is the file

If I select everything and use "Clear Transformations", then I get this:

I have a macro that allows me to apply "Clear Transformations" to shapes while retaining specified alignment for each shape. If I go back to your file as received, then use that macro, specifying that the left X, bottom Y position of each shape be retained, I get this:

Here's the macro code:

Sub clear_trans_keep_LeftXBottomY()
Dim sr As ShapeRange
Dim s As Shape
Dim LeftX_original As Double
Dim BottomY_original As Double

    Optimization = True
    ActiveDocument.BeginCommandGroup "Clear Trans keep LeftX BotY"
    EventsEnabled = False
    On Error GoTo ErrHandler
    
    Set sr = ActiveSelectionRange
    If sr.Count = 0 Then
        MsgBox "Nothing is selected.", vbExclamation
    Else
        For Each s In sr
            LeftX_original = s.LeftX
            BottomY_original = s.BottomY
            s.ClearTransformations
            s.LeftX = LeftX_original
            s.BottomY = BottomY_original
        Next s
    End If
    
ExitSub:
    Optimization = False
    EventsEnabled = True
    Application.Refresh
    ActiveDocument.EndCommandGroup
    Exit Sub

ErrHandler:
    MsgBox "Error occurred: " & Err.Description
    Resume ExitSub
End Sub

Select everything, then run the macro.

Of course, it would be better to have the content come in correctly in the first place. If that's not to be had, then something like this macro might help to fix things up after the fact.