MACRO help! How to find widest distance ACROSS various objects?

GFXCA said:

I did it manually. The problem is that I don't have a macro to know when to stop when it finds the "widest point" of any of the shapes, and then leave in that position. (When the widest point is parallel to horizontal.)

Here's what I had in mind.

Sub rotate_widest_horizontal(ByRef TargetShape As Shape)
Dim ang As Double
Dim max_width As Double
Dim ang_max_width As Double

Application.Optimization = True
For ang = 0 To 180 Step 0.1
    TargetShape.RotationAngle = ang
    If TargetShape.SizeWidth > max_width Then
        max_width = TargetShape.SizeWidth
        ang_max_width = ang
    End If
Next ang

TargetShape.RotationAngle = ang_max_width
Application.Optimization = False
Application.Refresh
End Sub

To test that subroutine:

Sub test_rotate_widest_horizontal()
Dim s As Shape
Dim sr As ShapeRange
Set sr = ActiveSelectionRange
For Each s In sr
    rotate_widest_horizontal s
Next s
End Sub

That works, but it runs much faster if the incremental rotating / measuring is done on a virtual object:

Sub rotate_widest_horizontal_faster(ByRef TargetShape As Shape)
Dim sVirtual As Shape
Dim ang As Double
Dim max_width As Double
Dim ang_max_width As Double

Set sVirtual = TargetShape.TreeNode.GetCopy().VirtualShape
For ang = 0 To 180 Step 0.1
    sVirtual.RotationAngle = ang
    If sVirtual.SizeWidth > max_width Then
        max_width = sVirtual.SizeWidth
        ang_max_width = ang
    End If
Next ang

sVirtual.Delete
TargetShape.RotationAngle = ang_max_width
End Sub

with this to test it:

Sub test_rotate_widest_horizontal_faster()
Dim s As Shape
Dim sr As ShapeRange
Set sr = ActiveSelectionRange
For Each s In sr
    rotate_widest_horizontal_faster s
Next s
End Sub

Both versions of this appear to work correctly for me in CorelDraw X7.

Rereading the original post, I found that I didn't fully understand the desired final result - keeping the original rotation angle for the shape, but scaling it so that its largest possible dimension (when rotated) is a particular size.

I think that this does the job. I'm showing only a version that uses a virtual shape to figure out the scaling, but it could all be done (more slowly) using only the real shape.

Sub scale_for_max_dimension(ByRef TargetShape As Shape, ByVal MaxDimension As Double)
    Dim s As Shape
    Dim sVirtual As Shape
    Dim ang As Double
    Dim max_width As Double
    Dim x_center As Double
    Dim y_center As Double
    Dim scale_factor As Double
    
    'create virtual shape
    Set sVirtual = TargetShape.TreeNode.GetCopy().VirtualShape
    
    'try angles from 0 to 180 degrees, in 0.1-degree increments
    For ang = 0 To 180 Step 0.1
        'set rotation angle of virtual shape
        sVirtual.RotationAngle = ang
        'Is this the largest width measured so far?
        If sVirtual.SizeWidth > max_width Then
            max_width = sVirtual.SizeWidth
        End If
    Next ang
    
    'delete the virtual object
    sVirtual.Delete
    
    Set s = TargetShape
    
    'record original center positions of real object
    x_center = s.CenterX
    y_center = s.CenterY
    
    'scale the real object
    scale_factor = MaxDimension / max_width
    s.SizeWidth = s.SizeWidth * scale_factor
    s.SizeHeight = s.SizeHeight * scale_factor
    
    'reposition to original center positions
    s.CenterX = x_center
    s.CenterY = y_center
End Sub

Again, to test it. Here, the maximum possible dimension (when rotated) is being specified as 1.5 inches.

Sub test_scale_for_max_dimension()
Dim s As Shape
Dim sr As ShapeRange
Dim max_dimension As Double

max_dimension = 1.5

Set sr = ActiveSelectionRange
For Each s In sr
    scale_for_max_dimension s, max_dimension
Next s
End Sub

Not sure if there's an issue with these macros being attempted in CorelDraw X4 vs your test in X7, but all of these result in errors. (Or maybe I'm doing something wrong). Another note: the "sub" lines that end in () can be found when I try to run the macro, but the sub lines with text inside the () are not found at all.

Examples:
Sub scale_for_max_dimension(ByRef TargetShape As Shape, ByVal MaxDimension As Double) --> not found in the macro menu.

vs

Sub test_scale_for_max_dimension() --> found in macro menu. Will run, but with errors. Here's the error message "Compile error: Expected variable or procedure, not module"