ideas to create childrens dot to dot drawing pictures

Hi.

That's excellent Patti. You are the blend master, of course.

Here's a macro to accent Patti's method. It will auto-number all points on your blend. Use before breaking apart blend, select blend and run. Enjoy!

~John

Sub blendNumber()
    Dim sr As ShapeRange, sText As Shape, s As Shape
    Dim i&, dSize#, x#, y#, j&, xOffset#, yOffset#
   
    ActiveDocument.ReferencePoint = cdrTopLeft
    dSize = 9 'font size
    xOffset = -0.1
    yOffset = 0.1
    i = 1
   
    ActiveDocument.BeginCommandGroup "Number Blend"
    For Each s In ActivePage.Shapes
        If s.Type = cdrBlendGroupShape Then
            If i = 1 Then
                s.Effect.Blend.StartShape.GetPosition x, y
                Set sText = ActiveLayer.CreateArtisticText(x + xOffset, y + yOffset, CStr(i), , , , dSize)
                i = i + 1
            End If
            For j = s.Effect.Blend.BlendGroup.Shapes.count To 1 Step -1
                s.Effect.Blend.BlendGroup.Shapes(j).GetPosition x, y
                Set sText = ActiveLayer.CreateArtisticText(x + xOffset, y + yOffset, CStr(i), , , , dSize)
                i = i + 1
            Next j
            s.Effect.Blend.EndShape.GetPosition x, y
            Set sText = ActiveLayer.CreateArtisticText(x + xOffset, y + yOffset, CStr(i), , , , dSize)
        End If
    Next s
    ActiveDocument.EndCommandGroup
End Sub

Thankyou so very much

Patti.. I am smiling - was getting very sore wrist from endlessly clicking..

.....John.

Could I also ask what line in the macro to change to increment the alpha characters.

use both numbering and a -z 

I am so very grateful...

Hi.

Try this variation:

Option Explicit

Sub blendNumber()
    Dim sr As ShapeRange, sText As Shape, s As Shape
    Dim i&, dSize#, x#, y#, j&, xOffset#, yOffset#, strABC$
   
    ActiveDocument.ReferencePoint = cdrTopLeft
    dSize = 9 'font size
    xOffset = -0.1
    yOffset = 0.1
    i = 1
   
   
    ActiveDocument.BeginCommandGroup "Number Blend"
    For Each s In ActivePage.Shapes
        If s.Type = cdrBlendGroupShape Then
            If i = 1 Then
                strABC = ColLett(i)
                s.Effect.Blend.StartShape.GetPosition x, y
                Set sText = ActiveLayer.CreateArtisticText(x + xOffset, y + yOffset, strABC, , , , dSize)
                i = i + 1
            End If
            For j = s.Effect.Blend.BlendGroup.Shapes.count To 1 Step -1
                strABC = ColLett(i)
                s.Effect.Blend.BlendGroup.Shapes(j).GetPosition x, y
                Set sText = ActiveLayer.CreateArtisticText(x + xOffset, y + yOffset, strABC, , , , dSize)
                i = i + 1
            Next j
            strABC = ColLett(i)
            s.Effect.Blend.EndShape.GetPosition x, y
            Set sText = ActiveLayer.CreateArtisticText(x + xOffset, y + yOffset, strABC, , , , dSize)
        End If
    Next s
    ActiveDocument.EndCommandGroup
End Sub

Private Function ColLett(Col&) As String
    If Col > 26 Then
        ColLett = ColLett((Col - (Col Mod 26)) / 26) + Chr(Col Mod 26 + 64)
    Else
        ColLett = Chr(Col + 64)
    End If
End Function

Thankyou again...  Can I add a circle with each of the increments
ie one event to create the dot and number or alpha character..? ( I live in hope )

Also if its curved the offset (have tried a few changes but get this result

If I were going to do this, I'd probably use a blend, like Patti explained

But don't forget if it's just circles you need, you can also do that with Fit Text to Path

Some folks find that option a little easier to tweak

Use a font that has a round 'period'. You can adjust the spacing globally with the right hand arrow when you select the Shape tool

If you duplicate the path,  the number spacing can be adjusted with the Shape tool as well

Just another idea, like I said, I'd probably go with the Blend option

Starting week number 3 without heat, power or electricity so any chance of me being able to post a visual using the Fit Text to Path alternative .........is only a pipedream

Thanks for all the kind thoughts and wishes many have sent me in the past days, I really, really appreciate your concern

xoxoxoxo

Thanks ..... will test that out also

3 weeks, hope the world is a little kinder to you soon..