Changing an ellipse to circle using keyboard shortcut

hold CTRL and draw ellipse

There is, as far as I know, no modifier key that can be used in this case, but you can try the Coordinates docker.

Open the docker, select the ellipse, choose Circle (hidden under the Ellipse icon in the top row of icons in the docker), and click "Replace object".
Works fine but is a bit tedious if you have many ellipses to correct.

I'm pretty sure this could easily be done with a macro too, but I don't have the skills to write one.

Ronny Axelsson said:

I'm pretty sure this could easily be done with a macro too, but I don't have the skills to write one.

Here are a couple of subs that set the size of each selected object based on the larger (or smaller) of the two dimensions:

Sub Width_Height_Same_As_Larger_Multi()
Dim s As Shape

    ActiveDocument.BeginCommandGroup "W_H_Same_As_Larger_Multi"
    For Each s In ActiveSelectionRange
        If s.SizeWidth > s.SizeHeight Then
            s.SetSizeEx s.CenterX, s.CenterY, s.SizeWidth, s.SizeWidth
        Else
            If s.SizeHeight > s.SizeWidth Then
                s.SetSizeEx s.CenterX, s.CenterY, s.SizeHeight, s.SizeHeight
            End If
        End If
    Next s
    ActiveDocument.EndCommandGroup
End Sub

Sub Width_Height_Same_As_Smaller_Multi()
Dim s As Shape

    ActiveDocument.BeginCommandGroup "W_H_Same_As_Smaller_Multi"
    For Each s In ActiveSelectionRange
        If s.SizeWidth < s.SizeHeight Then
            s.SetSizeEx s.CenterX, s.CenterY, s.SizeWidth, s.SizeWidth
        Else
            If s.SizeHeight < s.SizeWidth Then
                s.SetSizeEx s.CenterX, s.CenterY, s.SizeHeight, s.SizeHeight
            End If
        End If
    Next s
    ActiveDocument.EndCommandGroup
End Sub

taydin said:

I'm looking for a modifier key combination that, when pressed, will force an ellipse back to be a circle. I know that I can go and set the width and height of the ellipse to be equal, but I want to streamline my work and do it with a keystroke if possible.

If you are willing to explore macros, that's one way to do this sort of thing.

Here's a .ZIP file that contains a .GMS file that has a couple of macro subs:

SetSize_Subs.zip

If you haven't worked with macros before, here's some information that might help you get started with that:

#1: Getting started with using VBA macros (What do you do with a .GMS file?).

#2: Workspace Customization - Using a VBA macro sub as a Command.

Some of that will look a bit different in more recent versions of CorelDRAW, e.g., you'll see a "Scripts" docker rather than a "Macro Manager".